1 files changed, 45 insertions, 3 deletions

diff --git a/lisp/cus-edit.el b/lisp/cus-edit.el
index 52677f435ee..87d8ecade54 100644
--- a/lisp/cus-edit.el
+++ b/lisp/cus-edit.el
@@ -1084,7 +1084,7 @@ even if it doesn't match the type.)
 \(fn [VARIABLE VALUE]...)"
   (declare (debug setq))
   (unless (evenp (length pairs))
-    (error "PAIRS must have an even number of variable/value members"))
+    (signal 'wrong-number-of-arguments (list 'setopt (length pairs))))
   (let ((expr nil))
     (while pairs
       (unless (symbolp (car pairs))
@@ -1100,12 +1100,54 @@ even if it doesn't match the type.)
   ;; Check that the type is correct.
   (when-let* ((type (get variable 'custom-type)))
     (unless (widget-apply (widget-convert type) :match value)
-      (warn "Value `%S' for variable `%s' does not match its type \"%s\""
-            value variable type)))
+      (warn "Value does not match %S's type `%S': %S" variable type value)))
   (put variable 'custom-check-value (list value))
   (funcall (or (get variable 'custom-set) #'set-default) variable value))
 
 ;;;###autoload
+(defmacro setopt-local (&rest pairs)
+  "Set buffer local VARIABLE/VALUE pairs, and return the final VALUE.
+This is like `setq-local', but is meant for user options instead of
+plain variables.  This means that `setopt-local' will execute any
+`custom-set' form associated with VARIABLE.  Unlike `setopt',
+`setopt-local' does not affect a user option's global value.
+
+Note that `setopt-local' will emit a warning if the type of a VALUE does
+not match the type of the corresponding VARIABLE as declared by
+`defcustom'.  (VARIABLE will be assigned the value even if it doesn't
+match the type.)
+
+Signal an error if a `custom-set' form does not support the
+`buffer-local' argument.
+
+\(fn [VARIABLE VALUE]...)"
+  (declare (debug setq))
+  (unless (evenp (length pairs))
+    (signal 'wrong-number-of-arguments (list 'setopt-local (length pairs))))
+  (let ((expr nil))
+    (while pairs
+      (unless (symbolp (car pairs))
+        (error "Attempting to set a non-symbol: %s" (car pairs)))
+      (push `(setopt--set-local ',(car pairs) ,(cadr pairs))
+            expr)
+      (setq pairs (cddr pairs)))
+    (macroexp-progn (nreverse expr))))
+
+;;;###autoload
+(defun setopt--set-local (variable value)
+  (custom-load-symbol variable)
+  ;; Check that the type is correct.
+  (when-let* ((type (get variable 'custom-type)))
+    (unless (widget-apply (widget-convert type) :match value)
+      (warn "Value does not match %S's type `%S': %S" variable type value)))
+  (condition-case _
+      (funcall (or (get variable 'custom-set)
+                   (lambda (x v &optional _) (set-local x v)))
+               variable value 'buffer-local)
+    (wrong-number-of-arguments
+     (error "The setter of %S does not support setopt-local" variable))))
+
+;;;###autoload
 (defun customize-save-variable (variable value &optional comment)
   "Set the default for VARIABLE to VALUE, and save it for future sessions.
 Return VALUE.