merge from trunk

5 files changed, 478 insertions, 87 deletions

diff --git a/test/ChangeLog b/test/ChangeLog
index 43c783857f3..7857000ba2f 100644
--- a/test/ChangeLog
+++ b/test/ChangeLog
@@ -1,3 +1,24 @@
+2013-01-15  Stefan Monnier  <monnier@iro.umontreal.ca>
+
+        * automated/advice-tests.el: Split up.  Add advice-test-preactivate.
+
+2013-01-14  Glenn Morris  <rgm@gnu.org>
+
+        * automated/compile-tests.el (compile-tests--test-regexps-data):
+        Fix interpretation of gnu line.col1-col2 format.  (Bug#13335)
+
+2013-01-10  Wolfgang Jenkner  <wjenkner@inode.at>
+
+        * automated/man-tests.el: New file.
+
+2013-01-09  Aaron S. Hawley  <aaron.s.hawley@gmail.com>
+
+        * automated/undo-tests.el (undo-test0): Adjust error to code change.
+
+2013-01-08  Aaron S. Hawley  <aaron.s.hawley@gmail.com>
+
+        * automated/undo-tests.el: New file.
+
 2012-12-27  Dmitry Gutov  <dgutov@yandex.ru>
 
         * automated/ruby-mode-tests.el
diff --git a/test/automated/advice-tests.el b/test/automated/advice-tests.el
index bc9135c92d0..8beaea64cd9 100644
--- a/test/automated/advice-tests.el
+++ b/test/automated/advice-tests.el
@@ -21,93 +21,112 @@
 
 ;;; Code:
 
-(ert-deftest advice-tests ()
+(ert-deftest advice-tests-nadvice ()
+  "Test nadvice code."
+  (defun sm-test1 (x) (+ x 4))
+  (should (equal (sm-test1 6) 10))
+  (advice-add 'sm-test1 :around (lambda (f y) (* (funcall f y) 5)))
+  (should (equal (sm-test1 6) 50))
+  (defun sm-test1 (x) (+ x 14))
+  (should (equal (sm-test1 6) 100))
+  (should (equal (null (get 'sm-test1 'defalias-fset-function)) nil))
+  (advice-remove 'sm-test1 (lambda (f y) (* (funcall f y) 5)))
+  (should (equal (sm-test1 6) 20))
+  (should (equal (get 'sm-test1 'defalias-fset-function) nil))
+
+  (advice-add 'sm-test3 :around
+              (lambda (f &rest args) `(toto ,(apply f args)))
+              '((name . wrap-with-toto)))
+  (defmacro sm-test3 (x) `(call-test3 ,x))
+  (should (equal (macroexpand '(sm-test3 56)) '(toto (call-test3 56)))))
+
+(ert-deftest advice-tests-advice ()
   "Test advice code."
-  (with-temp-buffer
-    (defun sm-test1 (x) (+ x 4))
-    (should (equal (sm-test1 6) 10))
-    (advice-add 'sm-test1 :around (lambda (f y) (* (funcall f y) 5)))
-    (should (equal (sm-test1 6) 50))
-    (defun sm-test1 (x) (+ x 14))
-    (should (equal (sm-test1 6) 100))
-    (should (equal (null (get 'sm-test1 'defalias-fset-function)) nil))
-    (advice-remove 'sm-test1 (lambda (f y) (* (funcall f y) 5)))
-    (should (equal (sm-test1 6) 20))
-    (should (equal (null (get 'sm-test1 'defalias-fset-function)) t))
-
-    (defun sm-test2 (x) (+ x 4))
-    (should (equal (sm-test2 6) 10))
-    (defadvice sm-test2 (around sm-test activate)
-       ad-do-it (setq ad-return-value (* ad-return-value 5)))
-    (should (equal (sm-test2 6) 50))
-    (ad-deactivate 'sm-test2)
-    (should (equal (sm-test2 6) 10))
-    (ad-activate 'sm-test2)
-    (should (equal (sm-test2 6) 50))
-    (defun sm-test2 (x) (+ x 14))
-    (should (equal (sm-test2 6) 100))
-    (should (equal (null (get 'sm-test2 'defalias-fset-function)) nil))
-    (ad-remove-advice 'sm-test2 'around 'sm-test)
-    (should (equal (sm-test2 6) 100))
-    (ad-activate 'sm-test2)
-    (should (equal (sm-test2 6) 20))
-    (should (equal (null (get 'sm-test2 'defalias-fset-function)) t))
-
-    (advice-add 'sm-test3 :around
-                 (lambda (f &rest args) `(toto ,(apply f args)))
-                 '((name . wrap-with-toto)))
-     (defmacro sm-test3 (x) `(call-test3 ,x))
-    (should (equal (macroexpand '(sm-test3 56)) '(toto (call-test3 56))))
-
-    (defadvice sm-test4 (around wrap-with-toto activate)
-       ad-do-it (setq ad-return-value `(toto ,ad-return-value)))
-     (defmacro sm-test4 (x) `(call-test4 ,x))
-    (should (equal (macroexpand '(sm-test4 56)) '(toto (call-test4 56))))
-    (defmacro sm-test4 (x) `(call-testq ,x))
-    (should (equal (macroexpand '(sm-test4 56)) '(toto (call-testq 56))))
-
-    ;; Combining old style and new style advices.
-    (defun sm-test5 (x) (+ x 4))
-    (should (equal (sm-test5 6) 10))
-    (advice-add 'sm-test5 :around (lambda (f y) (* (funcall f y) 5)))
-    (should (equal (sm-test5 6) 50))
-    (defadvice sm-test5 (around test activate)
-       ad-do-it (setq ad-return-value (+ ad-return-value 0.1)))
-    (should (equal (sm-test5 5) 45.1))
-    (ad-deactivate 'sm-test5)
-    (should (equal (sm-test5 6) 50))
-    (ad-activate 'sm-test5)
-    (should (equal (sm-test5 6) 50.1))
-    (defun sm-test5 (x) (+ x 14))
-    (should (equal (sm-test5 6) 100.1))
-    (advice-remove 'sm-test5 (lambda (f y) (* (funcall f y) 5)))
-    (should (equal (sm-test5 6) 20.1))
-
-    ;; This used to signal an error (bug#12858).
-    (autoload 'sm-test6 "foo")
-     (defadvice sm-test6 (around test activate)
-       ad-do-it)
-
-    ;; Check interaction between advice and called-interactively-p.
-    (defun sm-test7 (&optional x) (interactive) (+ (or x 7) 4))
-    (advice-add 'sm-test7 :around
-                (lambda (f &rest args)
-                  (list (cons 1 (called-interactively-p)) (apply f args))))
-    (should (equal (sm-test7) '((1 . nil) 11)))
-    (should (equal (call-interactively 'sm-test7) '((1 . t) 11)))
-    (let ((smi 7))
-      (advice-add 'sm-test7 :before
-                  (lambda (&rest args)
-                    (setq smi (called-interactively-p))))
-      (should (equal (list (sm-test7) smi)
-                     '(((1 . nil) 11) nil)))
-      (should (equal (list (call-interactively 'sm-test7) smi)
-                      '(((1 . t) 11) t))))
-    (advice-add 'sm-test7 :around
-                (lambda (f &rest args)
-                  (cons (cons 2 (called-interactively-p)) (apply f args))))
-    (should (equal (call-interactively 'sm-test7) '((2 . t) (1 . t) 11)))
-    ))
+  (defun sm-test2 (x) (+ x 4))
+  (should (equal (sm-test2 6) 10))
+  (defadvice sm-test2 (around sm-test activate)
+    ad-do-it (setq ad-return-value (* ad-return-value 5)))
+  (should (equal (sm-test2 6) 50))
+  (ad-deactivate 'sm-test2)
+  (should (equal (sm-test2 6) 10))
+  (ad-activate 'sm-test2)
+  (should (equal (sm-test2 6) 50))
+  (defun sm-test2 (x) (+ x 14))
+  (should (equal (sm-test2 6) 100))
+  (should (equal (null (get 'sm-test2 'defalias-fset-function)) nil))
+  (ad-remove-advice 'sm-test2 'around 'sm-test)
+  (should (equal (sm-test2 6) 100))
+  (ad-activate 'sm-test2)
+  (should (equal (sm-test2 6) 20))
+  (should (equal (null (get 'sm-test2 'defalias-fset-function)) t))
+
+  (defadvice sm-test4 (around wrap-with-toto activate)
+    ad-do-it (setq ad-return-value `(toto ,ad-return-value)))
+  (defmacro sm-test4 (x) `(call-test4 ,x))
+  (should (equal (macroexpand '(sm-test4 56)) '(toto (call-test4 56))))
+  (defmacro sm-test4 (x) `(call-testq ,x))
+  (should (equal (macroexpand '(sm-test4 56)) '(toto (call-testq 56))))
+
+  ;; This used to signal an error (bug#12858).
+  (autoload 'sm-test6 "foo")
+  (defadvice sm-test6 (around test activate)
+    ad-do-it))
+
+(ert-deftest advice-tests-combination ()
+  "Combining old style and new style advices."
+  (defun sm-test5 (x) (+ x 4))
+  (should (equal (sm-test5 6) 10))
+  (advice-add 'sm-test5 :around (lambda (f y) (* (funcall f y) 5)))
+  (should (equal (sm-test5 6) 50))
+  (defadvice sm-test5 (around test activate)
+    ad-do-it (setq ad-return-value (+ ad-return-value 0.1)))
+  (should (equal (sm-test5 5) 45.1))
+  (ad-deactivate 'sm-test5)
+  (should (equal (sm-test5 6) 50))
+  (ad-activate 'sm-test5)
+  (should (equal (sm-test5 6) 50.1))
+  (defun sm-test5 (x) (+ x 14))
+  (should (equal (sm-test5 6) 100.1))
+  (advice-remove 'sm-test5 (lambda (f y) (* (funcall f y) 5)))
+  (should (equal (sm-test5 6) 20.1)))
+
+(ert-deftest advice-test-called-interactively-p ()
+  "Check interaction between advice and called-interactively-p."
+  (defun sm-test7 (&optional x) (interactive) (+ (or x 7) 4))
+  (advice-add 'sm-test7 :around
+              (lambda (f &rest args)
+                (list (cons 1 (called-interactively-p)) (apply f args))))
+  (should (equal (sm-test7) '((1 . nil) 11)))
+  (should (equal (call-interactively 'sm-test7) '((1 . t) 11)))
+  (let ((smi 7))
+    (advice-add 'sm-test7 :before
+                (lambda (&rest args)
+                  (setq smi (called-interactively-p))))
+    (should (equal (list (sm-test7) smi)
+                   '(((1 . nil) 11) nil)))
+    (should (equal (list (call-interactively 'sm-test7) smi)
+                   '(((1 . t) 11) t))))
+  (advice-add 'sm-test7 :around
+              (lambda (f &rest args)
+                (cons (cons 2 (called-interactively-p)) (apply f args))))
+  (should (equal (call-interactively 'sm-test7) '((2 . t) (1 . t) 11))))
+
+(ert-deftest advice-test-interactive ()
+  "Check handling of interactive spec."
+  (defun sm-test8 (a) (interactive "p") a)
+  (defadvice sm-test8 (before adv1 activate) nil)
+  (defadvice sm-test8 (before adv2 activate) (interactive "P") nil)
+  (should (equal (interactive-form 'sm-test8) '(interactive "P"))))
+
+(ert-deftest advice-test-preactivate ()
+  (should (equal (null (get 'sm-test9 'defalias-fset-function)) t))
+  (defun sm-test9 (a) (interactive "p") a)
+  (should (equal (null (get 'sm-test9 'defalias-fset-function)) t))
+  (defadvice sm-test9 (before adv1 pre act protect compile) nil)
+  (should (equal (null (get 'sm-test9 'defalias-fset-function)) nil))
+  (defadvice sm-test9 (before adv2 pre act protect compile)
+    (interactive "P") nil)
+  (should (equal (interactive-form 'sm-test9) '(interactive "P"))))
 
 ;; Local Variables:
 ;; no-byte-compile: t
diff --git a/test/automated/compile-tests.el b/test/automated/compile-tests.el
index f976efe72de..682867d1178 100644
--- a/test/automated/compile-tests.el
+++ b/test/automated/compile-tests.el
@@ -176,8 +176,10 @@
     ("foo.c:8.23: note: message" 1 23 8 "foo.c")
     ("foo.c:8.23: info: message" 1 23 8 "foo.c")
     ("foo.c:8:23:information: message" 1 23 8 "foo.c")
-    ("foo.c:8.23-45: Informational: message" 1 (23 . nil) (8 . 45) "foo.c")
+    ("foo.c:8.23-45: Informational: message" 1 (23 . 46) (8 . nil) "foo.c")
     ("foo.c:8-23: message" 1 nil (8 . 23) "foo.c")
+    ;; The next one is not in the GNU standards AFAICS.
+    ;; Here we seem to interpret it as LINE1-LINE2.COL2.
     ("foo.c:8-45.3: message" 1 (nil . 4) (8 . 45) "foo.c")
     ("foo.c:8.23-9.1: message" 1 (23 . 2) (8 . 9) "foo.c")
     ("jade:dbcommon.dsl:133:17:E: missing argument for function call"
diff --git a/test/automated/man-tests.el b/test/automated/man-tests.el
new file mode 100644
index 00000000000..8a2ec953002
--- /dev/null
+++ b/test/automated/man-tests.el
@@ -0,0 +1,118 @@
+;;; man-tests.el --- Test suite for man.
+
+;; Copyright (C) 2013  Free Software Foundation, Inc.
+
+;; Author: Wolfgang Jenkner <wjenkner@inode.at>
+;; Keywords: help, internal, unix
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
+
+;;; Code:
+
+(require 'ert)
+(require 'man)
+
+(defconst man-tests-parse-man-k-tests
+  '(;; GNU/Linux: man-db-2.6.1
+    ("\
+sin (3)              - sine function
+sinf (3)             - sine function
+sinl (3)             - sine function"
+     . (#("sin(3)" 0 6 (help-echo "sine function")) #("sinf(3)" 0 7 (help-echo "sine function")) #("sinl(3)" 0 7 (help-echo "sine function"))))
+    ;; GNU/Linux: man-1.6g
+    ("\
+sin                  (3)  - sine function
+sinf [sin]           (3)  - sine function
+sinl [sin]           (3)  - sine function"
+     . (#("sin(3)" 0 6 (help-echo "sine function")) #("sinf(3)" 0 7 (help-echo "sine function")) #("sinl(3)" 0 7 (help-echo "sine function"))))
+    ;; FreeBSD 9
+    ("\
+sin(3), sinf(3), sinl(3) - sine functions"
+     . (#("sin(3)" 0 6 (help-echo "sine functions")) #("sinf(3)" 0 7 (help-echo "sine functions")) #("sinl(3)" 0 7 (help-echo "sine functions"))))
+    ;; SunOS, Solaris
+    ;; http://docs.oracle.com/cd/E19455-01/805-6331/usradm-7/index.html
+    ;; SunOS 4
+    ("\
+tset, reset (1)    - establish or restore terminal characteristics"
+     . (#("tset(1)" 0 7 (help-echo "establish or restore terminal characteristics")) #("reset(1)" 0 8 (help-echo "establish or restore terminal characteristics"))))
+    ;; SunOS 5.7, Solaris
+    ("\
+reset  tset (1b)   - establish or restore terminal characteristics
+tset   tset (1b)   - establish or restore terminal characteristics"
+     . (#("reset(1b)" 0 8 (help-echo "establish or restore terminal characteristics")) #("tset(1b)" 0 7 (help-echo "establish or restore terminal characteristics"))))
+    ;; Minix 3
+    ;; http://www.minix3.org/manpages/html5/whatis.html
+    ("\
+cawf, nroff (1) - C version of the nroff-like, Amazingly Workable (text) Formatter
+whatis (5) - database of online manual pages"
+     . (#("cawf(1)" 0 7 (help-echo "C version of the nroff-like, Amazingly Workable (text) Formatter")) #("nroff(1)" 0 8 (help-echo "C version of the nroff-like, Amazingly Workable (text) Formatter")) #("whatis(5)" 0 9 (help-echo "database of online manual pages"))))
+    ;; HP-UX
+    ;; http://docstore.mik.ua/manuals/hp-ux/en/B2355-60130/man.1.html
+    ;; Assuming that the line break in the zgrep description was
+    ;; introduced by the man page formatting.
+    ("\
+grep, egrep, fgrep (1) - search a file for a pattern
+zgrep(1) - search possibly compressed files for a regular expression"
+     . (#("grep(1)" 0 7 (help-echo "search a file for a pattern")) #("egrep(1)" 0 8 (help-echo "search a file for a pattern")) #("fgrep(1)" 0 8 (help-echo "search a file for a pattern")) #("zgrep(1)" 0 8 (help-echo "search possibly compressed files for a regular expression"))))
+    ;; AIX
+    ;; http://pic.dhe.ibm.com/infocenter/aix/v7r1/topic/com.ibm.aix.cmds/doc/aixcmds6/whatis.htm
+    ("\
+ls(1)  -Displays the contents of a directory."
+    . (#("ls(1)" 0 5 (help-echo "Displays the contents of a directory."))))
+    ;; https://www.ibm.com/developerworks/mydeveloperworks/blogs/cgaix/entry/catman_0703_102_usr_lbin_mkwhatis_the_error_number_is_1?lang=en
+    ("\
+loopmount(1)    - Associate an image file to a loopback device."
+     . (#("loopmount(1)" 0 12 (help-echo "Associate an image file to a loopback device."))))
+    )
+  "List of tests for `Man-parse-man-k'.
+Each element is a cons cell whose car is a string containing
+man -k output.  That should result in the table which is stored
+in the cdr of the element.")
+
+(defun man-tests-name-equal-p (name description string)
+  (and (equal name string)
+       (not (next-single-property-change 0 'help-echo string))
+       (equal (get-text-property 0 'help-echo string) description)))
+
+(defun man-tests-parse-man-k-test-case (test)
+  (let ((temp-buffer (get-buffer-create " *test-man*"))
+        (man-k-output (car test)))
+    (unwind-protect
+        (save-window-excursion
+          (with-current-buffer temp-buffer
+            (erase-buffer)
+            (insert man-k-output)
+            (let ((result (Man-parse-man-k))
+                  (checklist (cdr test)))
+              (while (and checklist result
+                          (man-tests-name-equal-p
+                           (car checklist)
+                           (get-text-property 0 'help-echo
+                                              (car checklist))
+                           (pop result)))
+                (pop checklist))
+              (and (null checklist) (null result)))))
+      (and (buffer-name temp-buffer)
+           (kill-buffer temp-buffer)))))
+
+(ert-deftest man-tests ()
+  "Test man."
+  (dolist (test man-tests-parse-man-k-tests)
+    (should (man-tests-parse-man-k-test-case test))))
+
+(provide 'man-tests)
+
+;;; man-tests.el ends here
diff --git a/test/automated/undo-tests.el b/test/automated/undo-tests.el
new file mode 100644
index 00000000000..3037db03602
--- /dev/null
+++ b/test/automated/undo-tests.el
@@ -0,0 +1,231 @@
+;;; undo-tests.el --- Tests of primitive-undo
+
+;; Copyright (C) 2012  Aaron S. Hawley
+
+;; Author: Aaron S. Hawley <aaron.s.hawley@gmail.com>
+
+;; This program is free software: you can redistribute it and/or
+;; modify it under the terms of the GNU General Public License as
+;; published by the Free Software Foundation, either version 3 of the
+;; License, or (at your option) any later version.
+;;
+;; This program is distributed in the hope that it will be useful, but
+;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+;; General Public License for more details.
+;;
+;; You should have received a copy of the GNU General Public License
+;; along with this program.  If not, see `http://www.gnu.org/licenses/'.
+
+;;; Commentary:
+
+;; Profiling when the code was translate from C to Lisp on 2012-12-24.
+
+;;; C
+
+;; (elp-instrument-function 'primitive-undo)
+;; (load-file "undo-test.elc")
+;; (benchmark 100 '(let ((undo-test5-error nil)) (undo-test-all)))
+;; Elapsed time: 305.218000s (104.841000s in 14804 GCs)
+;; M-x elp-results
+;; Function Name   Call Count  Elapsed Time  Average Time
+;; primitive-undo  2600        3.4889999999  0.0013419230
+
+;;; Lisp
+
+;; (load-file "primundo.elc")
+;; (elp-instrument-function 'primitive-undo)
+;; (benchmark 100 '(undo-test-all))
+;; Elapsed time: 295.974000s (104.582000s in 14704 GCs)
+;; M-x elp-results
+;; Function Name   Call Count  Elapsed Time  Average Time
+;; primitive-undo  2700        3.6869999999  0.0013655555
+
+;;; Code:
+
+(require 'ert)
+
+(ert-deftest undo-test0 ()
+  "Test basics of \\[undo]."
+  (with-temp-buffer
+    (buffer-enable-undo)
+    (condition-case err
+      (undo)
+      (error
+       (unless (string= "No further undo information"
+                        (cadr err))
+         (error err))))
+    (undo-boundary)
+    (insert "This")
+    (undo-boundary)
+    (erase-buffer)
+    (undo-boundary)
+    (insert "That")
+    (undo-boundary)
+    (forward-word -1)
+    (undo-boundary)
+    (insert "With ")
+    (undo-boundary)
+    (forward-word -1)
+    (undo-boundary)
+    (kill-word 1)
+    (undo-boundary)
+    (put-text-property (point-min) (point-max) 'face 'bold)
+    (undo-boundary)
+    (remove-text-properties (point-min) (point-max) '(face default))
+    (undo-boundary)
+    (set-buffer-multibyte (not enable-multibyte-characters))
+    (undo-boundary)
+    (undo)
+    (should
+     (equal (should-error (undo-more nil))
+            '(wrong-type-argument number-or-marker-p nil)))
+    (undo-more 7)
+    (should (string-equal "" (buffer-string)))))
+
+(ert-deftest undo-test1 ()
+  "Test undo of \\[undo] command (redo)."
+  (with-temp-buffer
+    (buffer-enable-undo)
+    (undo-boundary)
+    (insert "This")
+    (undo-boundary)
+    (erase-buffer)
+    (undo-boundary)
+    (insert "That")
+    (undo-boundary)
+    (forward-word -1)
+    (undo-boundary)
+    (insert "With ")
+    (undo-boundary)
+    (forward-word -1)
+    (undo-boundary)
+    (kill-word 1)
+    (undo-boundary)
+    (facemenu-add-face 'bold (point-min) (point-max))
+    (undo-boundary)
+    (set-buffer-multibyte (not enable-multibyte-characters))
+    (undo-boundary)
+    (should
+     (string-equal (buffer-string)
+                   (progn
+                     (undo)
+                     (undo-more 4)
+                     (undo)
+                     ;(undo-more -4)
+                     (buffer-string))))))
+
+(ert-deftest undo-test2 ()
+  "Test basic redoing with \\[undo] command."
+  (with-temp-buffer
+    (buffer-enable-undo)
+    (undo-boundary)
+    (insert "One")
+    (undo-boundary)
+    (insert " Zero")
+    (undo-boundary)
+    (push-mark)
+    (delete-region (save-excursion
+                     (forward-word -1)
+                     (point)) (point))
+    (undo-boundary)
+    (beginning-of-line)
+    (insert "Zero")
+    (undo-boundary)
+    (undo)
+    (should
+     (string-equal (buffer-string)
+                   (progn
+                     (undo-more 2)
+                     (undo)
+                     (buffer-string))))))
+
+(ert-deftest undo-test3 ()
+  "Test modtime with \\[undo] command."
+  (let ((tmpfile (make-temp-file "undo-test3")))
+    (with-temp-file tmpfile
+      (let ((buffer-file-name tmpfile))
+        (buffer-enable-undo)
+        (set (make-local-variable 'make-backup-files) nil)
+        (undo-boundary)
+        (insert ?\s)
+        (undo-boundary)
+        (basic-save-buffer)
+        (insert ?\t)
+        (undo)
+        (should
+         (string-equal (buffer-string)
+                       (progn
+                         (undo)
+                         (buffer-string)))))
+      (delete-file tmpfile))))
+
+(ert-deftest undo-test4 ()
+  "Test \\[undo] of \\[flush-lines]."
+  (with-temp-buffer
+    (buffer-enable-undo)
+    (dotimes (i 1048576)
+      (if (zerop (% i 2))
+          (insert "Evenses")
+        (insert "Oddses")))
+    (undo-boundary)
+    (should
+     ;; Avoid string-equal because ERT will save the `buffer-string'
+     ;; to the explanation.  Using `not' will record nil or non-nil.
+     (not
+      (null
+       (string-equal (buffer-string)
+                     (progn
+                       (flush-lines "oddses" (point-min) (point-max))
+                       (undo-boundary)
+                       (undo)
+                       (undo)
+                       (buffer-string))))))))
+
+(ert-deftest undo-test5 ()
+  "Test basic redoing with \\[undo] command."
+  (with-temp-buffer
+    (buffer-enable-undo)
+    (undo-boundary)
+    (insert "AYE")
+    (undo-boundary)
+    (insert " BEE")
+    (undo-boundary)
+    (setq buffer-undo-list (cons '(0.0 bogus) buffer-undo-list))
+    (push-mark)
+    (delete-region (save-excursion
+                     (forward-word -1)
+                     (point)) (point))
+    (undo-boundary)
+    (beginning-of-line)
+    (insert "CEE")
+    (undo-boundary)
+    (undo)
+    (setq buffer-undo-list (cons "bogus" buffer-undo-list))
+    (should
+     (string-equal
+      (buffer-string)
+      (progn
+        (if (and (boundp 'undo-test5-error) (not undo-test5-error))
+            (progn
+              (should (null (undo-more 2)))
+              (should (undo)))
+          ;; Errors are generated by new Lisp version of
+          ;; `primitive-undo' not by built-in C version.
+          (should
+           (equal (should-error (undo-more 2))
+                  '(error "Unrecognized entry in undo list (0.0 bogus)")))
+          (should
+           (equal (should-error (undo))
+                  '(error "Unrecognized entry in undo list \"bogus\""))))
+        (buffer-string))))))
+
+(defun undo-test-all (&optional interactive)
+  "Run all tests for \\[undo]."
+  (interactive "p")
+  (if interactive
+      (ert-run-tests-interactively "^undo-")
+    (ert-run-tests-batch "^undo-")))
+
+(provide 'undo-tests)
+;;; undo-tests.el ends here