Merge from origin/emacs-25

c3489d0 * lisp/w32-fns.el (set-message-beep, w32-get-locale-info) (w3...
a4d882c Correct old cell name unbinding when renaming cell.
6c12c53 Merge branch 'emacs-25' of git.sv.gnu.org:/srv/git/emacs into...
0be6725 Document problem: slow screen refresh on missing font.
853b9b9 * admin/admin.el (add-release-logs): Basic check of existing ...
5fa80cf * build-aux/gitlog-to-emacslog: Handle empty generated Change...
3c79e51 * admin/admin.el (add-release-logs): Generate ChangeLog if ne...
42275df * doc/misc/texinfo.tex: Revert previous change (Bug#23611).
3f4a9d9 * admin/authors.el (authors): First update the ChangeLog.
897fb6f ; 'Changes from the pre-25.1 API' copyedits
825ca25 Rename vc-stay-local back to vc-cvs-stay-local
4efb3e8 * doc/emacs/files.texi (Comparing Files): * doc/emacs/trouble...
b995d1e * doc/misc/eww.texi (Advanced): Fix xref.
2e589c0 Fix cross-references between manuals
f3d2ded * doc/misc/vhdl-mode.texi (Sample Init File): Rename node to ...
906c810 ; * admin/release-process: Move etc/HISTORY from here... ; * ...
bea1b65 * admin/admin.el (add-release-logs): Also update etc/HISTORY.
503e752 ; * CONTRIBUTE: Fix a typo.
fbfd478 Avoid aborting due to errors in arguments of 'set-face-attrib...
bdfbe6d ; * admin/release-process: Copyedits.
44a6aed ; * test/automated/data-tests.el: Standardize license notice.
c33ed39 ; * test/automated/viper-tests.el: Standardize license notice.
df4a14b Add automated test for viper-tests.el
c0139e3 Fix viper undo breakage from undo-boundary changes
920d76c Fix reference to obsolete fn ps-eval-switch
18a9bc1 Do not trash symlinks to init file
2671179 Don't print the "decomposition" line for control chars in wha...
869092c Bring back xterm pasting with middle mouse
5ab0830 Provide workaround for xftfont rendering problem
c9f7ec7 * lisp/desktop.el: Disable restore frameset if in non-graphic...
30989a0 Mention GTK+ problems in etc/PROBLEMS
421e3c4 * lisp/emacs-lisp/package.el (package-refresh-contents):
dadfc30 Revert "epg: Add a way to detect gpg1 executable for tests"
e41a5cb Avoid errors with Czech and Slovak input methods
d4ae6d7 epg: Add a way to detect gpg1 executable for tests
ebc3a94 * lisp/emacs-lisp/package.el: Fix free variable warnings.
6e71295 * lisp/emacs-lisp/package.el (package--with-response-buffer):
c45d9f6 Improve documentation of 'server-name'
3b5e38c Modernize ASLR advice in etc/PROBLEMS
1fe1e0a * lisp/char-fold.el: Rename from character-fold.el.

4 files changed, 304 insertions, 13 deletions

diff --git a/test/automated/viper-tests.el b/test/automated/viper-tests.el
new file mode 100644
index 00000000000..8b30f050935
--- /dev/null
+++ b/test/automated/viper-tests.el
@@ -0,0 +1,160 @@
+;;; viper-tests.el --- tests for viper.
+
+;; Copyright (C) 2016 Free Software Foundation, Inc.
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;;; Code:
+
+
+(require 'viper)
+
+(defun viper-test-undo-kmacro (kmacro)
+  "In a clean viper buffer, run KMACRO and return `buffer-string'.
+
+This function makes as many attempts as possible to clean up
+after itself, although it will leave a buffer called
+*viper-test-buffer* if it fails (this is deliberate!)."
+  (let (
+        ;; Viper just turns itself off during batch use.
+        (noninteractive nil)
+        ;; Switch off start up message or it will chew the key presses
+        (viper-inhibit-startup-message 't)
+        ;; Select an expert-level for the same reason.
+        (viper-expert-level 5)
+        ;; viper loads this even with -q so make sure it's empty!
+        (viper-custom-file-name (make-temp-file "viper-tests"))
+        (before-buffer (current-buffer)))
+    (unwind-protect
+        (progn
+          ;; viper-mode is essentially global, so set it here
+          (viper-mode)
+          ;; We must switch to buffer because we are using a keyboard macro
+          ;; which appears to not go to the current-buffer but what ever is
+          ;; currently taking keyboard events. We use a named buffer because
+          ;; then we can see what it in it if it all goes wrong.
+          (switch-to-buffer
+           (get-buffer-create
+            "*viper-test-buffer*"))
+          (erase-buffer)
+          ;; The new buffer fails to enter vi state so set it.
+          (viper-change-state-to-vi)
+          ;; Run the macro
+          (execute-kbd-macro kmacro)
+          (let ((rtn
+                 (buffer-substring-no-properties
+                  (point-min)
+                  (point-max))))
+            ;; Kill the buffer iff the macro succeeds
+            (kill-buffer)
+            rtn))
+      ;; switch everthing off and restore the buffer
+      (toggle-viper-mode)
+      (switch-to-buffer before-buffer))))
+
+(ert-deftest viper-test-go ()
+  "Test that this file is running."
+  (should t))
+
+(ert-deftest viper-test-fix ()
+  "Test that the viper kmacro fixture is working."
+  (should
+   (viper-test-undo-kmacro [])))
+
+(ert-deftest viper-test-undo-1 ()
+  "Test for VI like undo behaviour.
+
+Insert 1, then 2 on consecutive lines, followed by undo. This
+should leave just 1 in the buffer.
+
+Test for Bug #22295"
+  (should
+   (equal
+    "1\n"
+    (viper-test-undo-kmacro
+     [
+      ?a
+      ?1
+      escape
+      ?o
+      ?2
+      escape
+      ?u
+      ]
+     ))))
+
+(ert-deftest viper-test-undo-2 ()
+  "Test for VI like undo behaviour.
+
+Insert \"1 2 3 4 5\" then delete the 2, then the 4, and undo.
+Should restore the 4, but leave the 2 deleted.
+
+Test for Bug #22295"
+  (should
+   (equal
+    "1 3 4 5\n"
+    (viper-test-undo-kmacro
+     [
+      ?i
+      ?1 ?  ?2 ?  ?3 ?  ?4 ?  ?5
+      escape
+      ?F ?2 ?d ?w
+      ?w ?d ?w
+      ?u
+      ]))))
+
+(ert-deftest viper-test-undo-3 ()
+  "Test for VI like undo behaviour.
+
+Insert \"1 2 3 4 5 6\", delete the 2, then the 3 4 and 5.
+Should restore the 3 4 and 5 but not the 2.
+
+Test for Bug #22295"
+  (should
+   (equal
+    "1 3 4 5 6\n"
+    (viper-test-undo-kmacro
+     [
+      ;; Insert this lot.
+      ?i ?1 ? ?2 ? ?3 ? ?4 ? ?5 ? ?6
+         escape
+         ;; Start of line.
+         ?0
+         ;; Move to 2, delete
+         ?w ?d ?w
+         ;; Delete 3 4 5
+         ?. ?. ?.
+         ;; Undo del 5, then
+         ?u ?. ?.
+         ]))))
+
+
+(ert-deftest viper-test-undo-4()
+  (should
+   (equal
+    ""
+    (viper-test-undo-kmacro
+     [
+      ?i ?1 escape
+         ?o ?2 escape
+         ?o ?3 escape
+         ?u ?. ?.
+         ])
+    )))
+
+;;; viper-tests.el ends here
diff --git a/test/lisp/char-fold-tests.el b/test/lisp/char-fold-tests.el
new file mode 100644
index 00000000000..485254aa6cf
--- /dev/null
+++ b/test/lisp/char-fold-tests.el
@@ -0,0 +1,124 @@
+;;; char-fold-tests.el --- Tests for char-fold.el  -*- lexical-binding: t; -*-
+
+;; Copyright (C) 2013-2016 Free Software Foundation, Inc.
+
+;; Author: Artur Malabarba <bruce.connor.am@gmail.com>
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
+
+;;; Code:
+
+(require 'ert)
+(require 'char-fold)
+
+(defun char-fold--random-word (n)
+  (mapconcat (lambda (_) (string (+ 9 (random 117))))
+             (make-list n nil) ""))
+
+(defun char-fold--test-search-with-contents (contents string)
+  (with-temp-buffer
+    (insert contents)
+    (goto-char (point-min))
+    (should (search-forward-regexp (char-fold-to-regexp string) nil 'noerror))
+    (goto-char (point-min))
+    (should (char-fold-search-forward string nil 'noerror))
+    (should (char-fold-search-backward string nil 'noerror))))
+
+
+(ert-deftest char-fold--test-consistency ()
+  (dotimes (n 30)
+    (let ((w (char-fold--random-word n)))
+      ;; A folded string should always match the original string.
+      (char-fold--test-search-with-contents w w))))
+
+(ert-deftest char-fold--test-lax-whitespace ()
+  (dotimes (n 40)
+    (let ((w1 (char-fold--random-word n))
+          (w2 (char-fold--random-word n))
+          (search-spaces-regexp "\\s-+"))
+      (char-fold--test-search-with-contents
+       (concat w1 "\s\n\s\t\f\t\n\r\t" w2)
+       (concat w1 " " w2))
+      (char-fold--test-search-with-contents
+       (concat w1 "\s\n\s\t\f\t\n\r\t" w2)
+       (concat w1 (make-string 10 ?\s) w2)))))
+
+(defun char-fold--test-match-exactly (string &rest strings-to-match)
+  (let ((re (concat "\\`" (char-fold-to-regexp string) "\\'")))
+    (dolist (it strings-to-match)
+      (should (string-match re it)))
+    ;; Case folding
+    (let ((case-fold-search t))
+      (dolist (it strings-to-match)
+        (should (string-match (upcase re) (downcase it)))
+        (should (string-match (downcase re) (upcase it)))))))
+
+(ert-deftest char-fold--test-some-defaults ()
+  (dolist (it '(("ffl" . "ffl") ("ffi" . "ffi")
+                ("fi" . "fi") ("ff" . "ff")
+                ("ä" . "ä")))
+    (char-fold--test-search-with-contents (cdr it) (car it))
+    (let ((multi (char-table-extra-slot char-fold-table 0))
+          (char-fold-table (make-char-table 'char-fold-table)))
+      (set-char-table-extra-slot char-fold-table 0 multi)
+      (char-fold--test-match-exactly (car it) (cdr it)))))
+
+(ert-deftest char-fold--test-fold-to-regexp ()
+  (let ((char-fold-table (make-char-table 'char-fold-table))
+        (multi  (make-char-table 'char-fold-table)))
+    (set-char-table-extra-slot char-fold-table 0 multi)
+    (aset char-fold-table ?a "xx")
+    (aset char-fold-table ?1 "44")
+    (aset char-fold-table ?\s "-!-")
+    (char-fold--test-match-exactly "a1a1" "xx44xx44")
+    (char-fold--test-match-exactly "a1  a 1" "xx44-!--!-xx-!-44")
+    (aset multi ?a '(("1" . "99")
+                     ("2" . "88")
+                     ("12" . "77")))
+    (char-fold--test-match-exactly "a" "xx")
+    (char-fold--test-match-exactly "a1" "xx44" "99")
+    (char-fold--test-match-exactly "a12" "77" "xx442" "992")
+    (char-fold--test-match-exactly "a2" "88")
+    (aset multi ?1 '(("2" . "yy")))
+    (char-fold--test-match-exactly "a1" "xx44" "99")
+    (char-fold--test-match-exactly "a12" "77" "xx442" "992")
+    ;; Support for this case is disabled.  See function definition or:
+    ;; https://lists.gnu.org/archive/html/emacs-devel/2015-11/msg02562.html
+    ;; (char-fold--test-match-exactly "a12" "xxyy")
+    ))
+
+(ert-deftest char-fold--speed-test ()
+  (dolist (string (append '("tty-set-up-initial-frame-face"
+                            "tty-set-up-initial-frame-face-frame-faceframe-faceframe-faceframe-face")
+                          (mapcar #'char-fold--random-word '(10 50 100
+                                                                     50 100))))
+    (message "Testing %s" string)
+    ;; Make sure we didn't just fallback on the trivial search.
+    (should-not (string= (regexp-quote string)
+                         (char-fold-to-regexp string)))
+    (with-temp-buffer
+      (save-excursion (insert string))
+      (let ((time (time-to-seconds (current-time))))
+        ;; Our initial implementation of case-folding in char-folding
+        ;; created a lot of redundant paths in the regexp. Because of
+        ;; that, if a really long string "almost" matches, the regexp
+        ;; engine took a long time to realize that it doesn't match.
+        (should-not (char-fold-search-forward (concat string "c") nil 'noerror))
+        ;; Ensure it took less than a second.
+        (should (< (- (time-to-seconds (current-time))
+                      time)
+                   1))))))
+
+(provide 'char-fold-tests)
+;;; char-fold-tests.el ends here
diff --git a/test/lisp/emacs-lisp/package-tests.el b/test/lisp/emacs-lisp/package-tests.el
index 70e129cc4f5..c7a5cc7af22 100644
--- a/test/lisp/emacs-lisp/package-tests.el
+++ b/test/lisp/emacs-lisp/package-tests.el
@@ -475,8 +475,15 @@ Must called from within a `tar-mode' buffer."
       (package-initialize)
       (package-import-keyring keyring)
       (package-refresh-contents)
-      (should (package-install 'signed-good))
-      (should-error (package-install 'signed-bad))
+      (let ((package-check-signature 'allow-unsigned))
+        (should (package-install 'signed-good))
+        (should-error (package-install 'signed-bad)))
+      (let ((package-check-signature t))
+        (should (package-install 'signed-good))
+        (should-error (package-install 'signed-bad)))
+      (let ((package-check-signature nil))
+        (should (package-install 'signed-good))
+        (should (package-install 'signed-bad)))
       ;; Check if the installed package status is updated.
       (let ((buf (package-list-packages)))
         (package-menu-refresh)
diff --git a/test/src/data-tests.el b/test/src/data-tests.el
index 9ca5ac53333..0a292336f35 100644
--- a/test/src/data-tests.el
+++ b/test/src/data-tests.el
@@ -4,18 +4,18 @@
 
 ;; This file is part of GNU Emacs.
 
-;; This program is free software: you can redistribute it and/or
-;; modify it under the terms of the GNU General Public License as
-;; published by the Free Software Foundation, either version 3 of the
-;; License, or (at your option) any later version.
-;;
-;; This program is distributed in the hope that it will be useful, but
-;; WITHOUT ANY WARRANTY; without even the implied warranty of
-;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
-;; General Public License for more details.
-;;
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
 ;; You should have received a copy of the GNU General Public License
-;; along with this program.  If not, see `http://www.gnu.org/licenses/'.
+;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
 
 ;;; Commentary: