Improve syncing VC buffers before generating diffs

* lisp/vc/vc.el (vc-maybe-buffer-sync): Delete.  Correct
handling of indirect buffers is now implicitly achieved by
vc-buffer-sync-fileset.
(vc-buffer-sync-fileset): Make NOT-ESSENTIAL argument optional,
new MISSING-IN-DIRS optional argument.  Rewrite to handle
directories named in the fileset, not only files.
(vc-ediff): Replace call to vc-maybe-buffer-sync with a call to
vc-buffer-sync-fileset.
(vc-root-diff): Similarly replace call to vc-maybe-buffer-sync.
This means the user is prompted to save additional buffers, that
they likely want to save before generating the diffs.
* test/lisp/vc/vc-misc-tests.el: New file.

1 files changed, 67 insertions, 0 deletions

diff --git a/test/lisp/vc/vc-misc-tests.el b/test/lisp/vc/vc-misc-tests.el
new file mode 100644
index 00000000000..d19dda36d2f
--- /dev/null
+++ b/test/lisp/vc/vc-misc-tests.el
@@ -0,0 +1,67 @@
+;;; vc-misc-tests.el --- backend-agnostic VC tests  -*- lexical-binding:t -*-
+
+;; Copyright (C) 2025 Free Software Foundation, Inc.
+
+;; Author: Sean Whitton <spwhitton@spwhitton.name>
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;;; Code:
+
+(require 'ert-x)
+(require 'vc)
+
+(ert-deftest vc-test-buffer-sync-fileset ()
+  "Test `vc-buffer-sync-fileset'."
+  (cl-flet ((test-it (&rest args)
+              (let (buffers)
+                (cl-letf (((symbol-function 'vc-buffer-sync)
+                           (lambda (&rest _)
+                             (push (current-buffer) buffers))))
+                  (apply #'vc-buffer-sync-fileset args)
+                  (sort buffers)))))
+    (ert-with-temp-directory temp
+      (let* ((default-directory temp)
+             (present (find-file-noselect "present"))
+             (missing (find-file-noselect "missing"))
+             (only-present (list present))
+             (only-missing (list missing))
+             (missing+present (list missing present)))
+        (with-current-buffer present (basic-save-buffer))
+        (with-temp-file "unvisited")
+        ;; Regular behavior for files.
+        (should (equal (test-it `(Git ("missing")))
+                       only-missing))
+        (should (equal (test-it `(Git ("present" "missing")))
+                       missing+present))
+        ;; Regular behavior for directories.
+        (should (equal (test-it `(Git (,temp)))
+                       only-present))
+        ;; Two ways to override regular behavior for directories.
+        (should (equal (test-it `(Git (,temp)) nil t)
+                       missing+present))
+        (should (equal (test-it `(Git (,temp "missing")))
+                       missing+present))
+        ;; Doesn't sync PRESENT twice.
+        (should (equal (test-it `(Git ("present" ,temp)))
+                       only-present))
+        (should (equal (test-it `(Git ("missing" ,temp "present")))
+                       missing+present))))))
+
+(provide 'vc-misc-tests)
+;;; vc-misc-tests.el ends here