Merge branch 'master' of git.sv.gnu.org:/srv/git/emacs

5 files changed, 328 insertions, 0 deletions

diff --git a/test/src/callproc-tests.el b/test/src/callproc-tests.el
new file mode 100644
index 00000000000..46541aba78c
--- /dev/null
+++ b/test/src/callproc-tests.el
@@ -0,0 +1,39 @@
+;;; callproc-tests.el --- callproc.c tests -*- lexical-binding: t -*-
+
+;; Copyright (C) 2016 Free Software Foundation, Inc.
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
+
+;;; Code:
+
+(require 'ert)
+(eval-when-compile (require 'cl-lib))
+
+(ert-deftest initial-environment-preserved ()
+  "Check that `initial-environment' is not modified by Emacs (Bug #10980)."
+  (skip-unless (eq system-type 'windows-nt))
+  (cl-destructuring-bind (initial-shell shell)
+      (with-temp-buffer
+        (let ((process-environment (cons "SHELL" process-environment)))
+          (call-process (expand-file-name invocation-name invocation-directory)
+                        nil t nil
+                        "--batch" "-Q" "--eval"
+                        (prin1-to-string
+                         '(progn (prin1 (getenv-internal "SHELL" initial-environment))
+                                 (prin1 (getenv-internal "SHELL"))))))
+        (split-string-and-unquote (buffer-string)))
+    (should (equal initial-shell "nil"))
+    (should-not (equal initial-shell shell))))
diff --git a/test/src/chartab-tests.el b/test/src/chartab-tests.el
new file mode 100644
index 00000000000..016ddcdde61
--- /dev/null
+++ b/test/src/chartab-tests.el
@@ -0,0 +1,51 @@
+;;; chartab-tests.el --- Tests for char-tab.c
+
+;; Copyright (C) 2016 Free Software Foundation, Inc.
+
+;; Author: Eli Zaretskii <eliz@gnu.org>
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
+
+;;; Code:
+
+(require 'ert)
+
+(defun chartab-set-and-test (rng)
+  (let ((tbl (make-char-table nil nil))
+        (from (car rng))
+        (to (cdr rng)))
+    (set-char-table-range tbl rng t)
+    (should (eq (aref tbl from) t))
+    (should (eq (aref tbl to) t))
+    (should (eq (aref tbl (/ (+ from to) 2)) t))
+    (when (< to (max-char))
+      (should-not (eq (aref tbl (1+ to)) t)))
+    (when (> from 0)
+      (should-not (eq (aref tbl (1- from)) t)))))
+
+(ert-deftest chartab-test-range-setting ()
+  (mapc (lambda (elt)
+          (chartab-set-and-test elt))
+        '((0 . 127)
+          (128 . 256)
+          (#x1000 . #x1fff)
+          (#x1001 . #x2000)
+          (#x10000 . #x20000)
+          (#x10001 . #x1ffff)
+          (#x20000 . #x30000)
+          (#xe0e00 . #xe0ef6)
+          )))
+
+(provide 'chartab-tests)
+;;; chartab-tests.el ends here
diff --git a/test/src/editfns-tests.el b/test/src/editfns-tests.el
new file mode 100644
index 00000000000..2f90d1e7495
--- /dev/null
+++ b/test/src/editfns-tests.el
@@ -0,0 +1,136 @@
+;;; editfns-tests.el -- tests for editfns.c
+
+;; Copyright (C) 2016 Free Software Foundation, Inc.
+
+;; This file is part of GNU Emacs.
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
+
+;;; Code:
+
+(require 'ert)
+
+(ert-deftest format-properties ()
+  ;; Bug #23730
+  (should (ert-equal-including-properties
+           (format (propertize "%d" 'face '(:background "red")) 1)
+           #("1" 0 1 (face (:background "red")))))
+  (should (ert-equal-including-properties
+           (format (propertize "%2d" 'face '(:background "red")) 1)
+           #(" 1" 0 2 (face (:background "red")))))
+  (should (ert-equal-including-properties
+           (format (propertize "%02d" 'face '(:background "red")) 1)
+           #("01" 0 2 (face (:background "red")))))
+  (should (ert-equal-including-properties
+           (format (concat (propertize "%2d" 'x 'X)
+                           (propertize "a" 'a 'A)
+                           (propertize "b" 'b 'B))
+                   1)
+           #(" 1ab" 0 2 (x X) 2 3 (a A) 3 4 (b B))))
+
+  ;; Bug #5306
+  (should (ert-equal-including-properties
+           (format "%.10s"
+                   (concat "1234567890aaaa"
+                           (propertize "12345678901234567890" 'xxx 25)))
+           "1234567890"))
+  (should (ert-equal-including-properties
+           (format "%.10s"
+                   (concat "123456789"
+                           (propertize "12345678901234567890" 'xxx 25)))
+           #("1234567891" 9 10 (xxx 25))))
+
+  ;; Bug #23859
+  (should (ert-equal-including-properties
+           (format "%4s" (propertize "hi" 'face 'bold))
+           #("  hi" 2 4 (face bold))))
+
+  ;; Bug #23897
+  (should (ert-equal-including-properties
+           (format "%s" (concat (propertize "01234" 'face 'bold) "56789"))
+           #("0123456789" 0 5 (face bold))))
+  (should (ert-equal-including-properties
+           (format "%s" (concat (propertize "01" 'face 'bold)
+                                (propertize "23" 'face 'underline)
+                                "45"))
+           #("012345" 0 2 (face bold) 2 4 (face underline))))
+  ;; The last property range is extended to include padding on the
+  ;; right, but the first range is not extended to the left to include
+  ;; padding on the left!
+  (should (ert-equal-including-properties
+           (format "%12s" (concat (propertize "01234" 'face 'bold) "56789"))
+           #("  0123456789" 2 7 (face bold))))
+  (should (ert-equal-including-properties
+           (format "%-12s" (concat (propertize "01234" 'face 'bold) "56789"))
+           #("0123456789  " 0 5 (face bold))))
+  (should (ert-equal-including-properties
+           (format "%10s" (concat (propertize "01" 'face 'bold)
+                                  (propertize "23" 'face 'underline)
+                                  "45"))
+           #("    012345" 4 6 (face bold) 6 8 (face underline))))
+  (should (ert-equal-including-properties
+           (format "%-10s" (concat (propertize "01" 'face 'bold)
+                                   (propertize "23" 'face 'underline)
+                                   "45"))
+           #("012345    " 0 2 (face bold) 2 4 (face underline))))
+  (should (ert-equal-including-properties
+           (format "%-10s" (concat (propertize "01" 'face 'bold)
+                                   (propertize "23" 'face 'underline)
+                                   (propertize "45" 'face 'italic)))
+           #("012345    " 0 2 (face bold) 2 4 (face underline) 4 10 (face italic)))))
+
+;; Tests for bug#5131.
+(defun transpose-test-reverse-word (start end)
+  "Reverse characters in a word by transposing pairs of characters."
+  (let ((begm (make-marker))
+        (endm (make-marker)))
+    (set-marker begm start)
+    (set-marker endm end)
+    (while (> endm begm)
+      (progn (transpose-regions begm (1+ begm) endm (1+ endm) t)
+             (set-marker begm (1+ begm))
+             (set-marker endm (1- endm))))))
+
+(defun transpose-test-get-byte-positions (len)
+  "Validate character position to byte position translation."
+  (let ((bytes '()))
+    (dotimes (pos len)
+      (setq bytes (add-to-list 'bytes (position-bytes (1+ pos)) t)))
+    bytes))
+
+(ert-deftest transpose-ascii-regions-test ()
+  (with-temp-buffer
+    (erase-buffer)
+    (insert "abcd")
+    (transpose-test-reverse-word 1 4)
+    (should (string= (buffer-string) "dcba"))
+    (should (equal (transpose-test-get-byte-positions 5) '(1 2 3 4 5)))))
+
+(ert-deftest transpose-nonascii-regions-test-1 ()
+  (with-temp-buffer
+    (erase-buffer)
+    (insert "÷bcd")
+    (transpose-test-reverse-word 1 4)
+    (should (string= (buffer-string) "dcb÷"))
+    (should (equal (transpose-test-get-byte-positions 5) '(1 2 3 4 6)))))
+
+(ert-deftest transpose-nonascii-regions-test-2 ()
+  (with-temp-buffer
+    (erase-buffer)
+    (insert "÷ab\"äé")
+    (transpose-test-reverse-word 1 6)
+    (should (string= (buffer-string) "éä\"ba÷"))
+    (should (equal (transpose-test-get-byte-positions 7) '(1 3 5 6 7 8 10)))))
+
+;;; editfns-tests.el ends here
diff --git a/test/src/fns-tests.el b/test/src/fns-tests.el
index 848589692ea..c533bad3cdc 100644
--- a/test/src/fns-tests.el
+++ b/test/src/fns-tests.el
@@ -235,3 +235,13 @@
                    (backward-delete-char 1)
                    (buffer-hash))
                  (sha1 "foo"))))
+
+(ert-deftest fns-tests-mapcan ()
+  (should-error (mapcan))
+  (should-error (mapcan #'identity))
+  (should-error (mapcan #'identity (make-char-table 'foo)))
+  (should (equal (mapcan #'list '(1 2 3)) '(1 2 3)))
+  ;; `mapcan' is destructive
+  (let ((data '((foo) (bar))))
+    (should (equal (mapcan #'identity data) '(foo bar)))
+    (should (equal data                     '((foo bar) (bar))))))
diff --git a/test/src/regex-tests.el b/test/src/regex-tests.el
new file mode 100644
index 00000000000..00165ab0512
--- /dev/null
+++ b/test/src/regex-tests.el
@@ -0,0 +1,92 @@
+;;; regex-tests.el --- tests for regex.c functions -*- lexical-binding: t -*-
+
+;; Copyright (C) 2015-2016 Free Software Foundation, Inc.
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
+
+;;; Code:
+
+(require 'ert)
+
+(ert-deftest regex-word-cc-fallback-test ()
+  "Test that ‘[[:cc:]]*x’ matches ‘x’ (bug#24020).
+
+Test that a regex of the form \"[[:cc:]]*x\" where CC is
+a character class which matches a multibyte character X, matches
+string \"x\".
+
+For example, ‘[[:word:]]*\u2620’ regex (note: \u2620 is a word
+character) must match a string \"\u2420\"."
+  (dolist (class '("[[:word:]]" "\\sw"))
+    (dolist (repeat '("*" "+"))
+      (dolist (suffix '("" "b" "bar" "\u2620"))
+        (dolist (string '("" "foo"))
+          (when (not (and (string-equal repeat "+")
+                          (string-equal string "")))
+            (should (string-match (concat "^" class repeat suffix "$")
+                                  (concat string suffix)))))))))
+
+(defun regex--test-cc (name matching not-matching)
+  (should (string-match-p (concat "^[[:" name ":]]*$") matching))
+  (should (string-match-p (concat "^[[:" name ":]]*?\u2622$")
+                          (concat matching "\u2622")))
+  (should (string-match-p (concat "^[^[:" name ":]]*$") not-matching))
+  (should (string-match-p (concat "^[^[:" name ":]]*\u2622$")
+                          (concat not-matching "\u2622")))
+  (with-temp-buffer
+    (insert matching)
+    (let ((p (point)))
+      (insert not-matching)
+      (goto-char (point-min))
+      (skip-chars-forward (concat "[:" name ":]"))
+      (should (equal (point) p))
+      (skip-chars-forward (concat "^[:" name ":]"))
+      (should (equal (point) (point-max)))
+      (goto-char (point-min))
+      (skip-chars-forward (concat "[:" name ":]\u2622"))
+      (should (or (equal (point) p) (equal (point) (1+ p)))))))
+
+(ert-deftest regex-character-classes ()
+  "Perform sanity test of regexes using character classes.
+
+Go over all the supported character classes and test whether the
+classes and their inversions match what they are supposed to
+match.  The test is done using `string-match-p' as well as
+`skip-chars-forward'."
+  (let (case-fold-search)
+    (regex--test-cc "alnum" "abcABC012łąka" "-, \t\n")
+    (regex--test-cc "alpha" "abcABCłąka" "-,012 \t\n")
+    (regex--test-cc "digit" "012" "abcABCłąka-, \t\n")
+    (regex--test-cc "xdigit" "0123aBc" "łąk-, \t\n")
+    (regex--test-cc "upper" "ABCŁĄKA" "abc012-, \t\n")
+    (regex--test-cc "lower" "abcłąka" "ABC012-, \t\n")
+
+    (regex--test-cc "word" "abcABC012\u2620" "-, \t\n")
+
+    (regex--test-cc "punct" ".,-" "abcABC012\u2620 \t\n")
+    (regex--test-cc "cntrl" "\1\2\t\n" ".,-abcABC012\u2620 ")
+    (regex--test-cc "graph" "abcłąka\u2620-," " \t\n\1")
+    (regex--test-cc "print" "abcłąka\u2620-, " "\t\n\1")
+
+    (regex--test-cc "space" " \t\n\u2001" "abcABCł0123")
+    (regex--test-cc "blank" " \t" "\n\u2001")
+
+    (regex--test-cc "ascii" "abcABC012 \t\n\1" "łą\u2620")
+    (regex--test-cc "nonascii" "łą\u2622" "abcABC012 \t\n\1")
+    (regex--test-cc "unibyte" "abcABC012 \t\n\1" "łą\u2622")
+    (regex--test-cc "multibyte" "łą\u2622" "abcABC012 \t\n\1")))
+
+;;; regex-tests.el ends here