* bindings.el (global-map): Bind delete and DEL, the former to

delete-forward-char.

* mouse.el (mouse-region-delete-keys): Deleted.
(mouse-show-mark): Simplify.

* simple.el (delete-active-region): New option.
(delete-backward-char): Implement in Lisp.
(delete-forward-char): New command.

* src/cmds.c (Fdelete_backward_char): Move into Lisp.

4 files changed, 92 insertions, 24 deletions

diff --git a/lisp/ChangeLog b/lisp/ChangeLog
index d88b7dfab2c..089264183bc 100644
--- a/lisp/ChangeLog
+++ b/lisp/ChangeLog
@@ -1,3 +1,15 @@
+2010-06-28  Chong Yidong  <cyd@stupidchicken.com>
+
+        * simple.el (delete-active-region): New option.
+        (delete-backward-char): Implement in Lisp.
+        (delete-forward-char): New command.
+
+        * mouse.el (mouse-region-delete-keys): Deleted.
+        (mouse-show-mark): Simplify.
+
+        * bindings.el (global-map): Bind delete and DEL, the former to
+        delete-forward-char.
+
 2010-01-16  Lennart Borgman  <lennart.borgman@gmail.com>
 
         * progmodes/ruby-mode.el (ruby-mode-map): Don't bind TAB.
diff --git a/lisp/bindings.el b/lisp/bindings.el
index f9d3e75cf6e..4eab37edf46 100644
--- a/lisp/bindings.el
+++ b/lisp/bindings.el
@@ -822,6 +822,9 @@ if `inhibit-field-text-motion' is non-nil."
     (setq i (1+ i))))
 (define-key global-map [?\C-\M--] 'negative-argument)
 
+(define-key global-map "\177" 'delete-backward-char)
+(define-key global-map "\C-d" 'delete-forward-char)
+
 (define-key global-map "\C-k" 'kill-line)
 (define-key global-map "\C-w" 'kill-region)
 (define-key esc-map "w" 'kill-ring-save)
diff --git a/lisp/mouse.el b/lisp/mouse.el
index d1abb7dd4b1..f6ff37794a5 100644
--- a/lisp/mouse.el
+++ b/lisp/mouse.el
@@ -929,7 +929,7 @@ should only be used by mouse-drag-region."
   (mouse-minibuffer-check start-event)
   (setq mouse-selection-click-count-buffer (current-buffer))
   ;; We must call deactivate-mark before repositioning point.
-  ;; Otherwise, for select-active-regions non-nil, we get the wrong
+  ;; Otherwise, for `select-active-regions' non-nil, we get the wrong
   ;; selection if the user drags a region, clicks elsewhere to
   ;; reposition point, then middle-clicks to paste the selection.
   (deactivate-mark)
@@ -1263,11 +1263,6 @@ If MODE is 2 then do the same for lines."
 
 ;; Momentarily show where the mark is, if highlighting doesn't show it.
 
-(defcustom mouse-region-delete-keys '([delete] [deletechar] [backspace])
-  "List of keys that should cause the mouse region to be deleted."
-  :group 'mouse
-  :type '(repeat key-sequence))
-
 (defun mouse-show-mark ()
   (let ((inhibit-quit t)
         (echo-keystrokes 0)
@@ -1297,8 +1292,7 @@ If MODE is 2 then do the same for lines."
                                  'vertical-scroll-bar))
                         (and (memq 'down (event-modifiers event))
                              (not (key-binding key))
-                             (not (mouse-undouble-last-event events))
-                             (not (member key mouse-region-delete-keys)))))
+                             (not (mouse-undouble-last-event events)))))
         (and (consp event)
              (or (eq (car event) 'switch-frame)
                  (eq (posn-point (event-end event))
@@ -1311,22 +1305,9 @@ If MODE is 2 then do the same for lines."
                       (setq events nil)))))))
     ;; If we lost the selection, just turn off the highlighting.
     (unless ignore
-      ;; For certain special keys, delete the region.
-      (if (member key mouse-region-delete-keys)
-          (progn
-            ;; Since notionally this is a separate command,
-            ;; run all the hooks that would be run if it were
-            ;; executed separately.
-            (run-hooks 'post-command-hook)
-            (setq last-command this-command)
-            (setq this-original-command 'delete-region)
-            (setq this-command (or (command-remapping this-original-command)
-                                   this-original-command))
-            (run-hooks 'pre-command-hook)
-            (call-interactively this-command))
-        ;; Otherwise, unread the key so it gets executed normally.
-        (setq unread-command-events
-              (nconc events unread-command-events))))
+      ;; Unread the key so it gets executed normally.
+      (setq unread-command-events
+            (nconc events unread-command-events)))
     (setq quit-flag nil)
     (unless transient-mark-mode
       (delete-overlay mouse-drag-overlay))))
diff --git a/lisp/simple.el b/lisp/simple.el
index ef30e98dd1c..a7876335c17 100644
--- a/lisp/simple.el
+++ b/lisp/simple.el
@@ -844,6 +844,78 @@ Don't use this command in Lisp programs!
          (overlay-recenter (point))
          (recenter -3))))
 
+(defcustom delete-active-region t
+  "Whether single-char deletion commands delete an active region.
+This has an effect only if Transient Mark mode is enabled, and
+affects `delete-forward-char' and `delete-backward-char', though
+not `delete-char'.
+
+If the value is the symbol `kill', the active region is killed
+instead of deleted."
+  :type '(choice (const :tag "Delete active region" t)
+                 (const :tag "Kill active region" kill)
+                 (const :tag "Do ordinary deletion" nil))
+  :group 'editing
+  :version "24.1")
+
+(defun delete-backward-char (n &optional killflag)
+  "Delete the previous N characters (following if N is negative).
+If Transient Mark mode is enabled, the mark is active, and N is 1,
+delete the text in the region and deactivate the mark instead.
+To disable this, set `delete-active-region' to nil.
+
+Optional second arg KILLFLAG, if non-nil, means to kill (save in
+kill ring) instead of delete.  Interactively, N is the prefix
+arg, and KILLFLAG is set if N is explicitly specified.
+
+In Overwrite mode, single character backward deletion may replace
+tabs with spaces so as to back over columns, unless point is at
+the end of the line."
+  (interactive "p\nP")
+  (unless (integerp n)
+    (signal 'wrong-type-argument (list 'integerp n)))
+  (cond ((and (use-region-p)
+              delete-active-region
+              (= n 1))
+         ;; If a region is active, kill or delete it.
+         (if (eq delete-active-region 'kill)
+             (kill-region (region-beginning) (region-end))
+           (delete-region (region-beginning) (region-end))))
+        ;; In Overwrite mode, maybe untabify while deleting
+        ((null (or (null overwrite-mode)
+                   (<= n 0)
+                   (memq (char-before) '(?\t ?\n))
+                   (eobp)
+                   (eq (char-after) ?\n)))
+         (let* ((ocol (current-column))
+                (val (delete-char (- n) killflag)))
+           (save-excursion
+             (insert-char ?\s (- ocol (current-column)) nil))))
+        ;; Otherwise, do simple deletion.
+        (t (delete-char (- n) killflag))))
+
+(defun delete-forward-char (n &optional killflag)
+  "Delete the previous N characters (following if N is negative).
+If Transient Mark mode is enabled, the mark is active, and N is 1,
+delete the text in the region and deactivate the mark instead.
+To disable this, set `delete-active-region' to nil.
+
+Optional second arg KILLFLAG non-nil means to kill (save in kill
+ring) instead of delete.  Interactively, N is the prefix arg, and
+KILLFLAG is set if N was explicitly specified."
+  (interactive "p\nP")
+  (unless (integerp n)
+    (signal 'wrong-type-argument (list 'integerp n)))
+  (cond ((and (use-region-p)
+              delete-active-region
+              (= n 1))
+         ;; If a region is active, kill or delete it.
+         (if (eq delete-active-region 'kill)
+             (kill-region (region-beginning) (region-end))
+           (delete-region (region-beginning) (region-end))))
+        ;; Otherwise, do simple deletion.
+        (t (delete-char n killflag))))
+
 (defun mark-whole-buffer ()
   "Put point at beginning and mark at end of buffer.
 You probably should not use this function in Lisp programs;