Use connection-aware functions when getting the UID/GID in Eshell

This means, for example, that when using Tramp to sudo in Eshell, "rm"
queries the user before deleting anything (bug#63221).

* lisp/eshell/esh-util.el (eshell-user-login-name): New function...
* lisp/eshell/em-unix.el (eshell/whoami): ... use it.

* lisp/eshell/em-ls.el (eshell-ls-applicable): Use 'file-user-uid' and
'eshell-user-login-name'.
(eshell-ls-decorated-name): Use 'file-user-uid'.

* lisp/eshell/em-pred.el (eshell-predicate-alist): Use 'file-user-uid'
and 'file-group-gid'.

* lisp/eshell/em-unix.el (eshell-interactive-query): New widget...
(eshell-rm-interactive-query, eshell-mv-interactive-query)
(eshell-cp-interactive-query, eshell-ln-interactive-query): ... use
it.
(eshell-interactive-query-p): New function...
(eshell/rm, eshell/mv, eshell/cp, eshell/ln): ... use it.

* lisp/simple.el (file-group-gid): New function.

* lisp/net/ange-ftp.el (ange-ftp-file-group-gid): New function...
(file-group-gid): ... use it.

* lisp/net/tramp.el (tramp-handle-file-group-gid):
* lisp/net/tramp-archive.el (tramp-archive-handle-file-group-gid): New
functions.

* lisp/net/tramp.el (tramp-file-name-for-operation): Add
'file-group-gid'.

* lisp/net/tramp-adb.el (tramp-adb-file-name-handler-alist):
* lisp/net/tramp-archive.el (tramp-archive-file-name-handler-alist):
* lisp/net/tramp-crypt.el (tramp-crypt-file-name-handler-alist):
* lisp/net/tramp-gvfs.el (tramp-gvfs-file-name-handler-alist):
* lisp/net/tramp-rclone.el (tramp-rclone-file-name-handler-alist):
* lisp/net/tramp-sh.el (tramp-sh-file-name-handler-alist):
* lisp/net/tramp-smb.el (tramp-smb-file-name-handler-alist):
* lisp/net/tramp-sshfs.el (tramp-sshfs-file-name-handler-alist):
* lisp/net/tramp-sudoedit.el (tramp-sudoedit-file-name-handler-alist):
Add 'file-group-gid' mapping.

* test/lisp/net/tramp-tests.el (tramp-test44-file-user-group-ids):
* test/lisp/net/tramp-archive-tests.el
(tramp-archive-test44-file-user-group-ids): Add tests for
'file-group-gid'.

* doc/lispref/files.texi (Magic File Names): Mention 'file-group-gid'.

* doc/lispref/os.texi (User Identification): Document
'file-group-gid', and move 'group-real-gid' to match the order of
'user-real-uid'.

* etc/NEWS: Announce 'file-group-gid'.

16 files changed, 108 insertions, 25 deletions

diff --git a/lisp/eshell/em-ls.el b/lisp/eshell/em-ls.el
index 56c5f262789..9b53bf29559 100644
--- a/lisp/eshell/em-ls.el
+++ b/lisp/eshell/em-ls.el
@@ -199,9 +199,9 @@ calling FUNC with FILE as an argument."
   `(let ((owner (file-attribute-user-id ,attrs))
          (modes (file-attribute-modes ,attrs)))
      (cond ((cond ((numberp owner)
-                   (= owner (user-uid)))
+                   (= owner (file-user-uid)))
                   ((stringp owner)
-                   (or (string-equal owner (user-login-name))
+                   (or (string-equal owner (eshell-user-login-name))
                        (member owner (eshell-current-ange-uids)))))
             ;; The user owns this file.
             (not (eq (aref modes ,index) ?-)))
@@ -919,7 +919,7 @@ to use, and each member of which is the width of that column
               ((not (eshell-ls-filetype-p (cdr file) ?-))
                'eshell-ls-special)
 
-              ((and (/= (user-uid) 0) ; root can execute anything
+              ((and (/= (file-user-uid) 0) ; root can execute anything
                     (eshell-ls-applicable (cdr file) 3
                                           'file-executable-p (car file)))
                'eshell-ls-executable)
diff --git a/lisp/eshell/em-pred.el b/lisp/eshell/em-pred.el
index 2ccca092b86..bfb0dad60ef 100644
--- a/lisp/eshell/em-pred.el
+++ b/lisp/eshell/em-pred.el
@@ -87,11 +87,11 @@ ordinary strings."
     (?U . (lambda (file)                   ; owned by effective uid
             (if (file-exists-p file)
                 (= (file-attribute-user-id (file-attributes file))
-                   (user-uid)))))
+                   (file-user-uid)))))
     (?G . (lambda (file)               ; owned by effective gid
             (if (file-exists-p file)
                 (= (file-attribute-group-id (file-attributes file))
-                   (group-gid)))))
+                   (file-group-gid)))))
     (?* . (lambda (file)
             (and (file-regular-p file)
                  (not (file-symlink-p file))
diff --git a/lisp/eshell/em-unix.el b/lisp/eshell/em-unix.el
index a792493e071..b7ef0f0c40c 100644
--- a/lisp/eshell/em-unix.el
+++ b/lisp/eshell/em-unix.el
@@ -91,14 +91,29 @@ Otherwise, `rmdir' is required."
   :type 'boolean
   :group 'eshell-unix)
 
-(defcustom eshell-rm-interactive-query (= (user-uid) 0)
-  "If non-nil, `rm' will query before removing anything."
-  :type 'boolean
+(define-widget 'eshell-interactive-query 'radio
+  "When to interatively query the user about a particular operation.
+If t, always query.  If nil, never query.  If `root', query when
+the user is logged in as root (including when `default-directory'
+is remote with a root user)."
+  :args '((const :tag "Never" nil)
+          (const :tag "Always" t)
+          (const :tag "When root" root)))
+
+(defcustom eshell-rm-interactive-query 'root
+  "When `rm' should query before removing anything.
+If t, always query.  If nil, never query.  If `root', query when
+the user is logged in as root (including when `default-directory'
+is remote with a root user)."
+  :type 'eshell-interactive-query
   :group 'eshell-unix)
 
-(defcustom eshell-mv-interactive-query (= (user-uid) 0)
-  "If non-nil, `mv' will query before overwriting anything."
-  :type 'boolean
+(defcustom eshell-mv-interactive-query 'root
+  "When `mv' should query before overwriting anything.
+If t, always query.  If nil, never query.  If `root', query when
+the user is logged in as root (including when `default-directory'
+is remote with a root user)."
+  :type 'eshell-interactive-query
   :group 'eshell-unix)
 
 (defcustom eshell-mv-overwrite-files t
@@ -106,9 +121,12 @@ Otherwise, `rmdir' is required."
   :type 'boolean
   :group 'eshell-unix)
 
-(defcustom eshell-cp-interactive-query (= (user-uid) 0)
-  "If non-nil, `cp' will query before overwriting anything."
-  :type 'boolean
+(defcustom eshell-cp-interactive-query 'root
+  "When `cp' should query before overwriting anything.
+If t, always query.  If nil, never query.  If `root', query when
+the user is logged in as root (including when `default-directory'
+is remote with a root user)."
+  :type 'eshell-interactive-query
   :group 'eshell-unix)
 
 (defcustom eshell-cp-overwrite-files t
@@ -116,9 +134,12 @@ Otherwise, `rmdir' is required."
   :type 'boolean
   :group 'eshell-unix)
 
-(defcustom eshell-ln-interactive-query (= (user-uid) 0)
-  "If non-nil, `ln' will query before overwriting anything."
-  :type 'boolean
+(defcustom eshell-ln-interactive-query 'root
+  "When `ln' should query before overwriting anything.
+If t, always query.  If nil, never query.  If `root', query when
+the user is logged in as root (including when `default-directory'
+is remote with a root user)."
+  :type 'eshell-interactive-query
   :group 'eshell-unix)
 
 (defcustom eshell-ln-overwrite-files nil
@@ -159,6 +180,17 @@ Otherwise, Emacs will attempt to use rsh to invoke du on the remote machine."
 (defvar em-recursive)
 (defvar em-verbose)
 
+(defun eshell-interactive-query-p (value)
+  "Return non-nil if a command should query the user according to VALUE.
+If VALUE is nil, return nil (never query).  If `root', return
+non-nil if the user is logged in as root (including when
+`default-directory' is remote with a root user; see
+`file-user-uid').  If VALUE is any other non-nil value, return
+non-nil (always query)."
+  (if (eq value 'root)
+      (= (file-user-uid) 0)
+    value))
+
 (defun eshell/man (&rest args)
   "Invoke man, flattening the arguments appropriately."
   (funcall 'man (apply 'eshell-flatten-and-stringify args)))
@@ -249,7 +281,8 @@ argument."
      :usage "[OPTION]... FILE...
 Remove (unlink) the FILE(s).")
    (unless em-interactive
-     (setq em-interactive eshell-rm-interactive-query))
+     (setq em-interactive (eshell-interactive-query-p
+                           eshell-rm-interactive-query)))
    (if (and force-removal em-interactive)
        (setq em-interactive nil))
    (while args
@@ -523,7 +556,8 @@ Rename SOURCE to DEST, or move SOURCE(s) to DIRECTORY.
 [OPTION] DIRECTORY...")
    (let ((no-dereference t))
      (eshell-mvcpln-template "mv" "moving" 'rename-file
-                             eshell-mv-interactive-query
+                             (eshell-interactive-query-p
+                              eshell-mv-interactive-query)
                              eshell-mv-overwrite-files))))
 
 (put 'eshell/mv 'eshell-no-numeric-conversions t)
@@ -561,7 +595,8 @@ Copy SOURCE to DEST, or multiple SOURCE(s) to DIRECTORY.")
    (if archive
        (setq preserve t no-dereference t em-recursive t))
    (eshell-mvcpln-template "cp" "copying" 'copy-file
-                           eshell-cp-interactive-query
+                           (eshell-interactive-query-p
+                            eshell-cp-interactive-query)
                            eshell-cp-overwrite-files preserve)))
 
 (put 'eshell/cp 'eshell-no-numeric-conversions t)
@@ -594,7 +629,8 @@ with `--symbolic'.  When creating hard links, each TARGET must exist.")
                              (if symbolic
                                  'make-symbolic-link
                                'add-name-to-file)
-                             eshell-ln-interactive-query
+                             (eshell-interactive-query-p
+                              eshell-ln-interactive-query)
                              eshell-ln-overwrite-files))))
 
 (put 'eshell/ln 'eshell-no-numeric-conversions t)
@@ -960,7 +996,7 @@ Show wall-clock time elapsed during execution of COMMAND.")
 
 (defun eshell/whoami (&rest _args)
   "Make \"whoami\" Tramp aware."
-  (or (file-remote-p default-directory 'user) (user-login-name)))
+  (eshell-user-login-name))
 
 (defvar eshell-diff-window-config nil)
 
diff --git a/lisp/eshell/esh-util.el b/lisp/eshell/esh-util.el
index c0685757789..3608c78ba2b 100644
--- a/lisp/eshell/esh-util.el
+++ b/lisp/eshell/esh-util.el
@@ -502,6 +502,11 @@ list."
       (sit-for 0)
     (error nil)))
 
+(defun eshell-user-login-name ()
+  "Return the connection-aware value of the user's login name.
+See also `user-login-name'."
+  (or (file-remote-p default-directory 'user) (user-login-name)))
+
 (defun eshell-read-passwd-file (file)
   "Return an alist correlating gids to group names in FILE."
   (let (names)
diff --git a/lisp/net/ange-ftp.el b/lisp/net/ange-ftp.el
index e21367135d3..1c20a27801d 100644
--- a/lisp/net/ange-ftp.el
+++ b/lisp/net/ange-ftp.el
@@ -4381,7 +4381,11 @@ NEWNAME should be the name to give the new compressed or uncompressed file.")
       (ange-ftp-real-find-backup-file-name fn)))
 
 (defun ange-ftp-file-user-uid ()
-  ;; Return "don't  know" value.
+  ;; Return "don't know" value.
+  -1)
+
+(defun ange-ftp-file-group-gid ()
+  ;; Return "don't know" value.
   -1)
 
 ;;; Define the handler for special file names
@@ -4524,8 +4528,9 @@ NEWNAME should be the name to give the new compressed or uncompressed file.")
 (put 'file-notify-rm-watch 'ange-ftp 'ignore)
 (put 'file-notify-valid-p 'ange-ftp 'ignore)
 
-;; Return the "don't know' value for remote user uid.
+;; Return the "don't know" value for remote user uid and group gid.
 (put 'file-user-uid 'ange-ftp 'ange-ftp-file-user-uid)
+(put 'file-group-gid 'ange-ftp 'ange-ftp-file-group-gid)
 
 ;;; Define ways of getting at unmodified Emacs primitives,
 ;;; turning off our handler.
diff --git a/lisp/net/tramp-adb.el b/lisp/net/tramp-adb.el
index 5a8044f8a53..6c668640ba4 100644
--- a/lisp/net/tramp-adb.el
+++ b/lisp/net/tramp-adb.el
@@ -154,6 +154,7 @@ It is used for TCP/IP devices."
     (file-system-info . tramp-adb-handle-file-system-info)
     (file-truename . tramp-handle-file-truename)
     (file-user-uid . tramp-handle-file-user-uid)
+    (file-group-gid . tramp-handle-file-group-gid)
     (file-writable-p . tramp-adb-handle-file-writable-p)
     (find-backup-file-name . tramp-handle-find-backup-file-name)
     ;; `get-file-buffer' performed by default handler.
diff --git a/lisp/net/tramp-archive.el b/lisp/net/tramp-archive.el
index c2175612fa8..8de6d406817 100644
--- a/lisp/net/tramp-archive.el
+++ b/lisp/net/tramp-archive.el
@@ -266,6 +266,7 @@ It must be supported by libarchive(3).")
     (file-system-info . tramp-archive-handle-file-system-info)
     (file-truename . tramp-archive-handle-file-truename)
     (file-user-uid . tramp-archive-handle-file-user-uid)
+    (file-group-gid . tramp-archive-handle-file-group-gid)
     (file-writable-p . ignore)
     (find-backup-file-name . ignore)
     ;; `get-file-buffer' performed by default handler.
@@ -678,6 +679,13 @@ offered."
       ;; `file-user-uid' exists since Emacs 30.1.
       (tramp-compat-funcall 'file-user-uid))))
 
+(defun tramp-archive-handle-file-group-gid ()
+  "Like `group-gid' for file archives."
+  (with-parsed-tramp-archive-file-name default-directory nil
+    (let ((default-directory (file-name-directory archive)))
+      ;; `file-group-gid' exists since Emacs 30.1.
+      (tramp-compat-funcall 'file-group-gid))))
+
 (defun tramp-archive-handle-insert-directory
   (filename switches &optional wildcard full-directory-p)
   "Like `insert-directory' for file archives."
diff --git a/lisp/net/tramp-crypt.el b/lisp/net/tramp-crypt.el
index ea27c704587..4acf6938b84 100644
--- a/lisp/net/tramp-crypt.el
+++ b/lisp/net/tramp-crypt.el
@@ -205,6 +205,7 @@ If NAME doesn't belong to an encrypted remote directory, return nil."
     (file-system-info . tramp-crypt-handle-file-system-info)
     ;; `file-truename' performed by default handler.
     ;; `file-user-uid' performed by default-handler.
+    ;; `file-group-gid' performed by default-handler.
     (file-writable-p . tramp-crypt-handle-file-writable-p)
     (find-backup-file-name . tramp-handle-find-backup-file-name)
     ;; `get-file-buffer' performed by default handler.
diff --git a/lisp/net/tramp-gvfs.el b/lisp/net/tramp-gvfs.el
index 859f4870b80..cce34889000 100644
--- a/lisp/net/tramp-gvfs.el
+++ b/lisp/net/tramp-gvfs.el
@@ -831,6 +831,7 @@ It has been changed in GVFS 1.14.")
     (file-system-info . tramp-gvfs-handle-file-system-info)
     (file-truename . tramp-handle-file-truename)
     (file-user-uid . tramp-handle-file-user-uid)
+    (file-group-gid . tramp-handle-file-group-gid)
     (file-writable-p . tramp-handle-file-writable-p)
     (find-backup-file-name . tramp-handle-find-backup-file-name)
     ;; `get-file-buffer' performed by default handler.
diff --git a/lisp/net/tramp-rclone.el b/lisp/net/tramp-rclone.el
index 74295de4c29..aa869460589 100644
--- a/lisp/net/tramp-rclone.el
+++ b/lisp/net/tramp-rclone.el
@@ -119,6 +119,7 @@
     (file-system-info . tramp-rclone-handle-file-system-info)
     (file-truename . tramp-handle-file-truename)
     (file-user-uid . tramp-handle-file-user-uid)
+    (file-group-gid . tramp-handle-file-group-gid)
     (file-writable-p . tramp-handle-file-writable-p)
     (find-backup-file-name . tramp-handle-find-backup-file-name)
     ;; `get-file-buffer' performed by default handler.
diff --git a/lisp/net/tramp-sh.el b/lisp/net/tramp-sh.el
index 0369e19378c..eacf7084fd1 100644
--- a/lisp/net/tramp-sh.el
+++ b/lisp/net/tramp-sh.el
@@ -1097,6 +1097,7 @@ Format specifiers \"%s\" are replaced before the script is used.")
     (file-system-info . tramp-sh-handle-file-system-info)
     (file-truename . tramp-sh-handle-file-truename)
     (file-user-uid . tramp-handle-file-user-uid)
+    (file-group-gid . tramp-handle-file-group-gid)
     (file-writable-p . tramp-sh-handle-file-writable-p)
     (find-backup-file-name . tramp-handle-find-backup-file-name)
     ;; `get-file-buffer' performed by default handler.
diff --git a/lisp/net/tramp-smb.el b/lisp/net/tramp-smb.el
index 9a24403bb18..93e6266313d 100644
--- a/lisp/net/tramp-smb.el
+++ b/lisp/net/tramp-smb.el
@@ -270,6 +270,7 @@ See `tramp-actions-before-shell' for more info.")
     (file-system-info . tramp-smb-handle-file-system-info)
     (file-truename . tramp-handle-file-truename)
     (file-user-uid . tramp-handle-file-user-uid)
+    (file-group-gid . tramp-handle-file-group-gid)
     (file-writable-p . tramp-smb-handle-file-writable-p)
     (find-backup-file-name . tramp-handle-find-backup-file-name)
     ;; `get-file-buffer' performed by default handler.
diff --git a/lisp/net/tramp-sshfs.el b/lisp/net/tramp-sshfs.el
index fe126361ac3..d552f6c83fa 100644
--- a/lisp/net/tramp-sshfs.el
+++ b/lisp/net/tramp-sshfs.el
@@ -125,6 +125,7 @@
     (file-system-info . tramp-sshfs-handle-file-system-info)
     (file-truename . tramp-handle-file-truename)
     (file-user-uid . tramp-handle-file-user-uid)
+    (file-group-gid . tramp-handle-file-group-gid)
     (file-writable-p . tramp-sshfs-handle-file-writable-p)
     (find-backup-file-name . tramp-handle-find-backup-file-name)
     ;; `get-file-buffer' performed by default handler.
diff --git a/lisp/net/tramp-sudoedit.el b/lisp/net/tramp-sudoedit.el
index 941c1e8dd24..531a1591a16 100644
--- a/lisp/net/tramp-sudoedit.el
+++ b/lisp/net/tramp-sudoedit.el
@@ -115,6 +115,7 @@ See `tramp-actions-before-shell' for more info.")
     (file-system-info . tramp-sudoedit-handle-file-system-info)
     (file-truename . tramp-sudoedit-handle-file-truename)
     (file-user-uid . tramp-handle-file-user-uid)
+    (file-group-gid . tramp-handle-file-group-gid)
     (file-writable-p . tramp-sudoedit-handle-file-writable-p)
     (find-backup-file-name . tramp-handle-find-backup-file-name)
     ;; `get-file-buffer' performed by default handler.
diff --git a/lisp/net/tramp.el b/lisp/net/tramp.el
index ca95b6b6971..9729baeb0d4 100644
--- a/lisp/net/tramp.el
+++ b/lisp/net/tramp.el
@@ -2650,7 +2650,7 @@ Must be handled by the callers."
               ;; Emacs 29+ only.
               list-system-processes memory-info process-attributes
               ;; Emacs 30+ only.
-              file-user-uid))
+              file-user-uid file-group-gid))
     default-directory)
    ;; PROC.
    ((member operation '(file-notify-rm-watch file-notify-valid-p))
@@ -3939,6 +3939,15 @@ Let-bind it when necessary.")
         ;; consistency.
         tramp-unknown-id-integer)))
 
+(defun tramp-handle-file-group-gid ()
+  "Like `group-gid' for Tramp files."
+  (let ((v (tramp-dissect-file-name default-directory)))
+    (or (tramp-get-remote-gid v 'integer)
+        ;; Some handlers for `tramp-get-remote-gid' return nil if they
+        ;; can't get the GID; always return -1 in this case for
+        ;; consistency.
+        tramp-unknown-id-integer)))
+
 (defun tramp-handle-access-file (filename string)
   "Like `access-file' for Tramp files."
   (setq filename (file-truename filename))
diff --git a/lisp/simple.el b/lisp/simple.el
index 8d772eee8a8..c9960ed5e13 100644
--- a/lisp/simple.el
+++ b/lisp/simple.el
@@ -4753,6 +4753,18 @@ this function will instead return -1."
       (funcall handler 'file-user-uid)
     (user-uid)))
 
+(defun file-group-gid ()
+  "Return the connection-local effective gid.
+This is similar to `group-gid', but may invoke a file name handler
+based on `default-directory'.  See Info node `(elisp)Magic File
+Names'.
+
+If a file name handler is unable to retrieve the effective gid,
+this function will instead return -1."
+  (if-let ((handler (find-file-name-handler default-directory 'file-group-gid)))
+      (funcall handler 'file-group-gid)
+    (group-gid)))
+
 (defun max-mini-window-lines (&optional frame)
   "Compute maximum number of lines for echo area in FRAME.
 As defined by `max-mini-window-height'.  FRAME defaults to the