Merge from emacs-24; up to 2014-05-12T06:15:47Z!rgm@gnu.org

3 files changed, 173 insertions, 7 deletions

diff --git a/admin/ChangeLog b/admin/ChangeLog
index 7af23b779ef..87da4f7e26b 100644
--- a/admin/ChangeLog
+++ b/admin/ChangeLog
@@ -1,3 +1,11 @@
+2014-05-12  Glenn Morris  <rgm@gnu.org>
+
+        * find-gc.el: Move here from ../lisp/emacs-lisp.
+
+        * admin.el (set-version-in-file): Don't set identical version.
+        (set-version): Provide default version number.
+        (set-version, set-copyright): Give start/end messages.
+
 2014-04-18  Paul Eggert  <eggert@cs.ucla.edu>
 
         * notes/bzr: Update instructions for merging from gnulib.
diff --git a/admin/admin.el b/admin/admin.el
index 007cb06e592..7af9ffa4177 100644
--- a/admin/admin.el
+++ b/admin/admin.el
@@ -65,17 +65,25 @@ Optional argument DATE is the release date, default today."
   "Subroutine of `set-version' and `set-copyright'."
   (find-file (expand-file-name file root))
   (goto-char (point-min))
+  (setq version (format "%s" version))
   (unless (re-search-forward rx nil :noerror)
     (user-error "Version not found in %s" file))
-  (replace-match (format "%s" version) nil nil nil 1))
+  (if (not (equal version (match-string 1)))
+      (replace-match version nil nil nil 1)
+    (kill-buffer)
+    (message "No need to update `%s'" file)))
 
-;; TODO report the progress
 (defun set-version (root version)
   "Set Emacs version to VERSION in relevant files under ROOT.
 Root must be the root of an Emacs source tree."
-  (interactive "DEmacs root directory: \nsVersion number: ")
+  (interactive (list
+                (read-directory-name "Emacs root directory: " source-directory)
+                (read-string "Version number: "
+                             (replace-regexp-in-string "\\.[0-9]+\\'" ""
+                                                       emacs-version))))
   (unless (file-exists-p (expand-file-name "src/emacs.c" root))
     (user-error "%s doesn't seem to be the root of an Emacs source tree" root))
+  (message "Setting version numbers...")
   ;; There's also a "version 3" (standing for GPLv3) at the end of
   ;; `README', but since `set-version-in-file' only replaces the first
   ;; occurrence, it won't be replaced.
@@ -158,11 +166,10 @@ Root must be the root of an Emacs source tree."
 {\\([0-9]\\{2,\\}\\)}.+%.+version of Emacs")
       (set-version-in-file root "etc/refcards/emacsver.tex" version
                            "\\\\def\\\\versionemacs\
-{\\([0-9]\\{2,\\}\\)}.+%.+version of Emacs"))))
-
+{\\([0-9]\\{2,\\}\\)}.+%.+version of Emacs")))
+  (message "Setting version numbers...done"))
 
 ;; Note this makes some assumptions about form of short copyright.
-;; TODO report the progress
 (defun set-copyright (root copyright)
   "Set Emacs short copyright to COPYRIGHT in relevant files under ROOT.
 Root must be the root of an Emacs source tree."
@@ -174,6 +181,7 @@ Root must be the root of an Emacs source tree."
                          (format-time-string "%Y")))))
   (unless (file-exists-p (expand-file-name "src/emacs.c" root))
     (user-error "%s doesn't seem to be the root of an Emacs source tree" root))
+  (message "Setting copyrights...")
   (set-version-in-file root "configure.ac" copyright
                        (rx (and bol "copyright" (0+ (not (in ?\")))
                                 ?\" (submatch (1+ (not (in ?\")))) ?\")))
@@ -195,7 +203,8 @@ Root must be the root of an Emacs source tree."
 {\\([0-9]\\{4\\}\\)}.+%.+copyright year")
     (set-version-in-file root "etc/refcards/emacsver.tex" copyright
                          "\\\\def\\\\year\
-{\\([0-9]\\{4\\}\\)}.+%.+copyright year")))
+{\\([0-9]\\{4\\}\\)}.+%.+copyright year"))
+  (message "Setting copyrights...done"))
 
 ;;; Various bits of magic for generating the web manuals
 
diff --git a/admin/find-gc.el b/admin/find-gc.el
new file mode 100644
index 00000000000..83eb26e86d7
--- /dev/null
+++ b/admin/find-gc.el
@@ -0,0 +1,149 @@
+;;; find-gc.el --- detect functions that call the garbage collector
+
+;; Copyright (C) 1992, 2001-2014 Free Software Foundation, Inc.
+
+;; Maintainer: emacs-devel@gnu.org
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;; Produce in find-gc-unsafe-list the set of all functions that may invoke GC.
+;; This expects the Emacs sources to live in find-gc-source-directory.
+
+;;; Code:
+
+(defvar find-gc-unsafe-list nil
+  "The list of unsafe functions is placed here by `find-gc-unsafe'.")
+
+(defvar find-gc-source-directory
+  (file-name-as-directory (expand-file-name "src" source-directory))
+  "Directory containing Emacs C sources.")
+
+(defvar find-gc-subrs-callers nil
+  "Alist of users of subrs, from GC testing.
+Each entry has the form (FUNCTION . FUNCTIONS-THAT-CALL-IT).")
+
+(defvar find-gc-subrs-called nil
+  "Alist of subrs called, in GC testing.
+Each entry has the form (FUNCTION . FUNCTIONS-IT-CALLS).")
+
+
+;;; Functions on this list are safe, even if they appear to be able
+;;; to call the target.
+
+(defvar find-gc-noreturn-list '(Fsignal Fthrow wrong_type_argument))
+
+;;; This was originally generated directory-files, but there were
+;;; too many files there that were not actually compiled.  The
+;;; list below was created for a HP-UX 7.0 system.
+
+(defvar find-gc-source-files
+  '("dispnew.c" "scroll.c" "xdisp.c" "window.c"
+    "term.c" "cm.c" "emacs.c" "keyboard.c" "macros.c"
+    "keymap.c" "sysdep.c" "buffer.c" "filelock.c"
+    "insdel.c" "marker.c" "minibuf.c" "fileio.c"
+    "dired.c" "cmds.c" "casefiddle.c"
+    "indent.c" "search.c" "regex.c" "undo.c"
+    "alloc.c" "data.c" "doc.c" "editfns.c"
+    "callint.c" "eval.c" "fns.c" "print.c" "lread.c"
+    "syntax.c" "unexcoff.c"
+    "bytecode.c" "process.c" "callproc.c" "doprnt.c"
+    "xterm.c" "xfns.c"))
+
+
+(defun find-gc-unsafe ()
+  "Return a list of unsafe functions--that is, which can call GC.
+Also store it in `find-gc-unsafe-list'."
+  (trace-call-tree nil)
+  (trace-use-tree)
+  (find-unsafe-funcs 'Fgarbage_collect)
+  (setq find-gc-unsafe-list
+        (sort find-gc-unsafe-list
+              (function (lambda (x y)
+                          (string-lessp (car x) (car y)))))))
+
+;;; This does a depth-first search to find all functions that can
+;;; ultimately call the function "target".  The result is an a-list
+;;; in find-gc-unsafe-list; the cars are the unsafe functions, and the cdrs
+;;; are (one of) the unsafe functions that these functions directly
+;;; call.
+
+(defun find-unsafe-funcs (target)
+  (setq find-gc-unsafe-list (list (list target)))
+  (trace-unsafe target))
+
+(defun trace-unsafe (func)
+  (let ((used (assq func find-gc-subrs-callers)))
+    (or used
+        (error "No find-gc-subrs-callers for %s" (car find-gc-unsafe-list)))
+    (while (setq used (cdr used))
+      (or (assq (car used) find-gc-unsafe-list)
+          (memq (car used) find-gc-noreturn-list)
+          (progn
+            (push (cons (car used) func) find-gc-unsafe-list)
+            (trace-unsafe (car used)))))))
+
+
+
+
+(defun trace-call-tree (&optional ignored)
+  (message "Setting up directories...")
+  (setq find-gc-subrs-called nil)
+  (let ((case-fold-search nil)
+        (default-directory find-gc-source-directory)
+        (files find-gc-source-files)
+        name entry rtlfile)
+    (dolist (file files)
+      (message "Compiling %s..." file)
+      (call-process "gcc" nil nil nil "-I" "." "-I" "../lib"
+                    "-fdump-rtl-expand" "-o" null-device "-c" file)
+      (setq rtlfile
+            (file-expand-wildcards (format "%s.*.expand" file) t))
+      (if (/= 1 (length rtlfile))
+          (message "Error compiling `%s'?" file)
+        (with-temp-buffer
+          (insert-file-contents (setq rtlfile (car rtlfile)))
+          (delete-file rtlfile)
+          (while (re-search-forward ";; Function \\|(call_insn " nil t)
+            (if (= (char-after (- (point) 3)) ?o)
+                (progn
+                  (looking-at "[a-zA-Z0-9_]+")
+                  (setq name (intern (match-string 0)))
+                  (message "%s : %s" (car files) name)
+                  (setq entry (list name)
+                        find-gc-subrs-called
+                        (cons entry find-gc-subrs-called)))
+              (if (looking-at ".*\n?.*\"\\([A-Za-z0-9_]+\\)\"")
+                  (progn
+                    (setq name (intern (match-string 1)))
+                    (or (memq name (cdr entry))
+                        (setcdr entry (cons name (cdr entry)))))))))))))
+
+(defun trace-use-tree ()
+  (setq find-gc-subrs-callers (mapcar 'list (mapcar 'car find-gc-subrs-called)))
+  (let ((ptr find-gc-subrs-called)
+        p2 found)
+    (while ptr
+      (setq p2 (car ptr))
+      (while (setq p2 (cdr p2))
+        (if (setq found (assq (car p2) find-gc-subrs-callers))
+            (setcdr found (cons (car (car ptr)) (cdr found)))))
+      (setq ptr (cdr ptr)))))
+
+(provide 'find-gc)
+
+;;; find-gc.el ends here